Newer
Older
Juan Escobar
committed
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
!MNH_LIC Copyright 1994-2020 CNRS, Meteo-France and Universite Paul Sabatier
!MNH_LIC This is part of the Meso-NH software governed by the CeCILL-C licence
!MNH_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt
!MNH_LIC for details. version 1.
!-----------------------------------------------------------------
! ####################
MODULE MODI_CONTRAV
! ####################
!
INTERFACE
!
SUBROUTINE CONTRAV(HLBCX,HLBCY,PRUT,PRVT,PRWT,PDXX,PDYY,PDZZ,PDZX,PDZY, &
PRUCT,PRVCT,PRWCT,KADV_ORDER )
!
!
CHARACTER (LEN=4), DIMENSION(2), INTENT(IN) :: HLBCX ! X direction LBC type
CHARACTER (LEN=4), DIMENSION(2), INTENT(IN) :: HLBCY ! Y direction LBC type
REAL, DIMENSION(:,:,:), INTENT(IN) :: PRUT ! Cartesian comp along x
REAL, DIMENSION(:,:,:), INTENT(IN) :: PRVT ! Cartesian comp along y
REAL, DIMENSION(:,:,:), INTENT(IN) :: PRWT ! Cartesian comp along z
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDXX ! Metric coefficients
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDYY ! Metric coefficients
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDZZ ! Metric coefficients
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDZX ! Metric coefficients
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDZY ! Metric coefficients
REAL, DIMENSION(:,:,:), INTENT(OUT) :: PRUCT ! Contrav comp along x-bar
REAL, DIMENSION(:,:,:), INTENT(OUT) :: PRVCT ! Contrav comp along y-bar
REAL, DIMENSION(:,:,:), INTENT(OUT) :: PRWCT ! Contrav comp along z-bar
INTEGER, INTENT(IN) :: KADV_ORDER ! Order of the advection scheme
!
END SUBROUTINE CONTRAV
!
#ifdef MNH_OPENACC
SUBROUTINE CONTRAV_DEVICE(HLBCX,HLBCY,PRUT,PRVT,PRWT,PDXX,PDYY,PDZZ,PDZX,PDZY, &
PRUCT,PRVCT,PRWCT,KADV_ORDER,Z1,Z2,ODATA_ON_DEVICE )
!
!
CHARACTER (LEN=4), DIMENSION(2), INTENT(IN) :: HLBCX ! X direction LBC type
CHARACTER (LEN=4), DIMENSION(2), INTENT(IN) :: HLBCY ! Y direction LBC type
REAL, DIMENSION(:,:,:), INTENT(IN) :: PRUT ! Cartesian comp along x
REAL, DIMENSION(:,:,:), INTENT(IN) :: PRVT ! Cartesian comp along y
REAL, DIMENSION(:,:,:), INTENT(IN) :: PRWT ! Cartesian comp along z
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDXX ! Metric coefficients
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDYY ! Metric coefficients
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDZZ ! Metric coefficients
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDZX ! Metric coefficients
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDZY ! Metric coefficients
REAL, DIMENSION(:,:,:), INTENT(OUT) :: PRUCT ! Contrav comp along x-bar
REAL, DIMENSION(:,:,:), INTENT(OUT) :: PRVCT ! Contrav comp along y-bar
REAL, DIMENSION(:,:,:), INTENT(OUT) :: PRWCT ! Contrav comp along z-bar
INTEGER, INTENT(IN) :: KADV_ORDER ! Order of the advection scheme
REAL, DIMENSION(:,:,:), INTENT(OUT) :: Z1,Z2 ! Work arrays
LOGICAL, OPTIONAL, INTENT(IN) :: ODATA_ON_DEVICE ! Is some of the data on the accelerator device
!
!
END SUBROUTINE CONTRAV_DEVICE
#endif
!
END INTERFACE
!
END MODULE MODI_CONTRAV
!
!
!
! ##############################################################
SUBROUTINE CONTRAV(HLBCX,HLBCY,PRUT,PRVT,PRWT,PDXX,PDYY,PDZZ,PDZX,PDZY, &
PRUCT,PRVCT,PRWCT,KADV_ORDER )
! ##############################################################
!
!!**** *CONTRAV * - computes the contravariant components from the
!! cartesian components
!!
!! PURPOSE
!! -------
! This routine computes the contravariant components of vector
! defined by its cartesian components (U,V,W) , using the following
! formulae:
! UC = U / DXX
! VC = V / DYY
! ( ----------x ----------y )
! ( ---z ---z )
! 1 ( U V )
! WC = --- ( W - DZX * --- - DZY * --- )
! DZZ ( DXX DYY )
!
!
! In the no-topography case, WC = W / DZZ
!
!
!!** METHOD
!! ------
!! We employ the Shuman operators to compute the averages. The metric
!! coefficients PDXX, PDYY, PDZX, PDZY, PDZZ are dummy arguments
!!
!!
!! EXTERNAL
!! --------
!!
!!
!! IMPLICIT ARGUMENTS
!! ------------------
!!
!! Module MODD_CONF : contains configuration variable
!! LFLAT : Logical for topography
!! = .TRUE. if Zs = 0 (Flat terrain)
!!
!! REFERENCE
!! ---------
!! Book2 of documentation (subroutine CONTRAV)
!!
!!
!! AUTHOR
!! ------
!! J.L. Redelsperger * CNRM *
!! J.-P. Pinty * Laboratoire d'Aerologie*
!!
!! MODIFICATIONS
!! -------------
!! Original 27/07/94
!! Corrections 3/08/94 (by J.P. Lafore)
!! Corrections 17/10/94 (by J.P. Lafore) WC modified for w-advection
!! Corrections 19/01/11 (by J.P. Pinty) WC 4th order
!! Corrections 28/03/11 (by V.Masson) // of WC 4th order
!! J.Escobar 21/03/2013: for HALOK comment all NHALO=1 test
! P. Wautelet 20/05/2019: add name argument to ADDnFIELD_ll + new ADD4DFIELD_ll subroutine
!----------------------------------------------------------------------------
!
!* 0. DECLARATIONS
! ------------
USE MODD_CONF
USE MODD_PARAMETERS
USE MODD_GRID_n, ONLY: XZZ
!
USE MODD_ARGSLIST_ll, ONLY : HALO2LIST_ll
USE MODE_ll
!
USE MODI_GET_HALO
!
USE MODE_MPPDB
!
IMPLICIT NONE
!
!* 0.1 declarations of arguments
!
CHARACTER (LEN=4), DIMENSION(2), INTENT(IN) :: HLBCX ! X direction LBC type
CHARACTER (LEN=4), DIMENSION(2), INTENT(IN) :: HLBCY ! Y direction LBC type
!
REAL, DIMENSION(:,:,:), INTENT(IN) :: PRUT ! Cartesian comp along x
REAL, DIMENSION(:,:,:), INTENT(IN) :: PRVT ! Cartesian comp along y
REAL, DIMENSION(:,:,:), INTENT(IN) :: PRWT ! Cartesian comp along z
!
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDXX ! Metric coefficients
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDYY ! Metric coefficients
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDZZ ! Metric coefficients
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDZX ! Metric coefficients
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDZY ! Metric coefficients
!
!
REAL, DIMENSION(:,:,:), INTENT(OUT) :: PRUCT ! Contrav comp along x-bar
REAL, DIMENSION(:,:,:), INTENT(OUT) :: PRVCT ! Contrav comp along y-bar
REAL, DIMENSION(:,:,:), INTENT(OUT) :: PRWCT ! Contrav comp along z-bar
INTEGER, INTENT(IN) :: KADV_ORDER ! Order of the advection scheme
!
!
!* 0.2 declarations of local variables
!
REAL, DIMENSION(SIZE(PDXX,1),SIZE(PDXX,2),SIZE(PDXX,3)):: Z1,Z2
INTEGER :: IIB,IIE,IJB,IJE,IKB,IKE
INTEGER :: IIU, IJU, IKU
INTEGER:: IW,IE,IS,IN ! Coordinate of forth order diffusion area
!
TYPE(LIST_ll), POINTER :: TZFIELD_U, TZFIELD_V, TZFIELD_DZX, TZFIELD_DZY
TYPE(HALO2LIST_ll), POINTER :: TZHALO2_U, TZHALO2_V, TZHALO2_DZX, TZHALO2_DZY
INTEGER :: IINFO_ll
!-----------------------------------------------------------------------
!
!* 1. Compute the horizontal contravariant components
! -----------------------------------------------
!
IF (MPPDB_INITIALIZED) THEN
!Check all IN arrays
CALL MPPDB_CHECK(PRUT,"CONTRAV beg:PRUT")
CALL MPPDB_CHECK(PRVT,"CONTRAV beg:PRVT")
CALL MPPDB_CHECK(PRWT,"CONTRAV beg:PRWT")
CALL MPPDB_CHECK(PDXX,"CONTRAV beg:PDXX")
CALL MPPDB_CHECK(PDYY,"CONTRAV beg:PDYY")
CALL MPPDB_CHECK(PDZZ,"CONTRAV beg:PDZZ")
CALL MPPDB_CHECK(PDZX,"CONTRAV beg:PDZX")
CALL MPPDB_CHECK(PDZY,"CONTRAV beg:PDZY")
END IF
!
IIU= SIZE(PDXX,1)
IJU= SIZE(PDXX,2)
IKU= SIZE(PDXX,3)
!
CALL GET_INDICE_ll( IIB,IJB,IIE,IJE)
!
IKB=1+JPVEXT
IKE=IKU - JPVEXT
!
PRUCT(:,:,:) = PRUT(:,:,:) / PDXX(:,:,:)
PRVCT(:,:,:) = PRVT(:,:,:) / PDYY(:,:,:)
!
IF (KADV_ORDER == 4 ) THEN
IF( .NOT. LFLAT) THEN
NULLIFY(TZFIELD_U)
NULLIFY(TZFIELD_V)
CALL ADD3DFIELD_ll( TZFIELD_U, PRUCT, 'CONTRAV::PRUCT' )
CALL ADD3DFIELD_ll( TZFIELD_V, PRVCT, 'CONTRAV::PRVCT' )
CALL UPDATE_HALO_ll(TZFIELD_U,IINFO_ll)
CALL UPDATE_HALO_ll(TZFIELD_V,IINFO_ll)
!!$ IF( NHALO==1 ) THEN
NULLIFY(TZFIELD_DZX)
NULLIFY(TZFIELD_DZY)
CALL ADD3DFIELD_ll( TZFIELD_DZX, PDZX, 'CONTRAV::PDZX' )
CALL ADD3DFIELD_ll( TZFIELD_DZY, PDZY, 'CONTRAV::PDZY' )
NULLIFY(TZHALO2_U)
NULLIFY(TZHALO2_V)
NULLIFY(TZHALO2_DZX)
NULLIFY(TZHALO2_DZY)
CALL INIT_HALO2_ll(TZHALO2_U,1,IIU,IJU,IKU)
CALL INIT_HALO2_ll(TZHALO2_V,1,IIU,IJU,IKU)
CALL INIT_HALO2_ll(TZHALO2_DZX,1,IIU,IJU,IKU)
CALL INIT_HALO2_ll(TZHALO2_DZY,1,IIU,IJU,IKU)
CALL UPDATE_HALO2_ll(TZFIELD_U, TZHALO2_U, IINFO_ll)
CALL UPDATE_HALO2_ll(TZFIELD_V, TZHALO2_V, IINFO_ll)
CALL UPDATE_HALO2_ll(TZFIELD_DZX, TZHALO2_DZX, IINFO_ll)
CALL UPDATE_HALO2_ll(TZFIELD_DZY, TZHALO2_DZY, IINFO_ll)
!!$ END IF
END IF
END IF
!
!
!* 2. Compute the vertical contravariant components (flat case)
! ------------------------------------
!
IF (LFLAT) THEN
PRWCT(:,:,:) = PRWT(:,:,:) / PDZZ(:,:,:)
RETURN
END IF
!
!* 3. Compute the vertical contravariant components (general case)
! ------------------------------------
!
Z1 = 0.
Z2 = 0.
!
IF (KADV_ORDER == 2 ) THEN
!
Z1(IIB:IIE,:,IKB:IKE+1)= &
(PRUCT(IIB:IIE,:,IKB:IKE+1)+PRUCT(IIB:IIE,:,IKB-1:IKE) ) &
*PDZX(IIB:IIE,:,IKB:IKE+1) *0.25 &
+(PRUCT(IIB+1:IIE+1,:,IKB:IKE+1)+PRUCT(IIB+1:IIE+1,:,IKB-1:IKE) ) &
*PDZX(IIB+1:IIE+1,:,IKB:IKE+1) *0.25
Z2(:,IJB:IJE,IKB:IKE+1)= &
(PRVCT(:,IJB:IJE,IKB:IKE+1)+PRVCT(:,IJB:IJE,IKB-1:IKE) ) &
*PDZY(:,IJB:IJE,IKB:IKE+1) *0.25 &
+(PRVCT(:,IJB+1:IJE+1,IKB:IKE+1)+PRVCT(:,IJB+1:IJE+1,IKB-1:IKE) ) &
*PDZY(:,IJB+1:IJE+1,IKB:IKE+1) *0.25
PRWCT=0.
PRWCT(IIB:IIE,IJB:IJE,IKB:IKE+1) = &
( PRWT(IIB:IIE,IJB:IJE,IKB:IKE+1) &
- Z1(IIB:IIE,IJB:IJE,IKB:IKE+1) &
- Z2(IIB:IIE,IJB:IJE,IKB:IKE+1) &
) / PDZZ(IIB:IIE,IJB:IJE,IKB:IKE+1)
!
ELSE IF (KADV_ORDER == 4 ) THEN
!
!!$ IF (NHALO == 1) THEN
IF ( LWEST_ll() .AND. HLBCX(1)/='CYCL' ) THEN
IW=IIB+2 -1
ELSE
IW=IIB+1 -1
END IF
IE=IIE-1
!!$ ELSE
!!$ IF (LWEST_ll()) THEN
!!$ IW=IIB+1
!!$ ELSE
!!$ IW=IIB
!!$ END IF
!!$ IF (LEAST_ll() .AND. HLBCX(2)/='CYCL' ) THEN
!!$ IE=IIE-1
!!$ ELSE
!!$ IE=IIE
!!$ END IF
!!$ END IF
!
!!$ IF(NHALO == 1) THEN
IF ( LSOUTH_ll() .AND. HLBCY(1)/='CYCL' ) THEN
IS=IJB+2 -1
ELSE
IS=IJB+1 -1
END IF
IN=IJE-1
!!$ ELSE
!!$ IF (LSOUTH_ll()) THEN
!!$ IS=IJB+1
!!$ ELSE
!!$ IS=IJB
!!$ END IF
!!$ IF (LNORTH_ll() .AND. HLBCY(2)/='CYCL' ) THEN
!!$ IN=IJE-1
!!$ ELSE
!!$ IN=IJE
!!$ END IF
!!$ END IF
!
!
!* 3.1 interior of the process subdomain
!
!
Z1(IW:IE,:,IKB:IKE+1)= &
7.0*( (PRUCT(IW:IE,:,IKB:IKE+1)+PRUCT(IW:IE,:,IKB-1:IKE)) &
*( 9.0*PDZX(IW:IE,:,IKB:IKE+1)-(PDZX(IW+1:IE+1,:,IKB:IKE+1) &
+PDZX(IW:IE,:,IKB:IKE+1)+PDZX(IW-1:IE-1,:,IKB:IKE+1))/3.0)/8.0 * 0.5 &
+(PRUCT(IW+1:IE+1,:,IKB:IKE+1)+PRUCT(IW+1:IE+1,:,IKB-1:IKE)) &
*( 9.0*PDZX(IW+1:IE+1,:,IKB:IKE+1)-(PDZX(IW+2:IE+2,:,IKB:IKE+1) &
+PDZX(IW+1:IE+1,:,IKB:IKE+1)+PDZX(IW:IE,:,IKB:IKE+1))/3.0)/8.0 * 0.5 )/12.0 &
-( (PRUCT(IW-1:IE-1,:,IKB:IKE+1)+PRUCT(IW-1:IE-1,:,IKB-1:IKE)) &
*PDZX(IW-1:IE-1,:,IKB:IKE+1) *0.5 &
+(PRUCT(IW+2:IE+2,:,IKB:IKE+1)+PRUCT(IW+2:IE+2,:,IKB-1:IKE)) &
*PDZX(IW+2:IE+2,:,IKB:IKE+1) *0.5)/12.0
!
Z2(:,IS:IN,IKB:IKE+1)= &
7.0*( (PRVCT(:,IS:IN,IKB:IKE+1)+PRVCT(:,IS:IN,IKB-1:IKE)) &
*( 9.0*PDZY(:,IS:IN,IKB:IKE+1)-(PDZY(:,IS+1:IN+1,IKB:IKE+1) &
+PDZY(:,IS:IN,IKB:IKE+1)+PDZY(:,IS-1:IN-1,IKB:IKE+1))/3.0)/8.0 * 0.5 &
+(PRVCT(:,IS+1:IN+1,IKB:IKE+1)+PRVCT(:,IS+1:IN+1,IKB-1:IKE)) &
*( 9.0*PDZY(:,IS+1:IN+1,IKB:IKE+1)-(PDZY(:,IS+2:IN+2,IKB:IKE+1) &
+PDZY(:,IS+1:IN+1,IKB:IKE+1)+PDZY(:,IS:IN,IKB:IKE+1))/3.0)/8.0 * 0.5 )/12.0 &
-( (PRVCT(:,IS-1:IN-1,IKB:IKE+1)+PRVCT(:,IS-1:IN-1,IKB-1:IKE)) &
*PDZY(:,IS-1:IN-1,IKB:IKE+1) *0.5 &
+(PRVCT(:,IS+2:IN+2,IKB:IKE+1)+PRVCT(:,IS+2:IN+2,IKB-1:IKE)) &
*PDZY(:,IS+2:IN+2,IKB:IKE+1) *0.5)/12.0
!
!* 3.2 limits of the process subdomain (inside the whole domain or in cyclic conditions)
!
!!$ IF (NHALO==1) THEN
Z1(IIE,:,IKB:IKE+1)= &
7.0*( (PRUCT(IIE,:,IKB:IKE+1)+PRUCT(IIE,:,IKB-1:IKE)) &
*( 9.0*PDZX(IIE,:,IKB:IKE+1)-(PDZX(IIE+1,:,IKB:IKE+1) &
+PDZX(IIE,:,IKB:IKE+1)+PDZX(IIE-1,:,IKB:IKE+1))/3.0)/8.0 * 0.5 &
+(PRUCT(IIE+1,:,IKB:IKE+1)+PRUCT(IIE+1,:,IKB-1:IKE)) &
*( 9.0*PDZX(IIE+1,:,IKB:IKE+1)-(TZHALO2_DZX%HALO2%EAST(:,IKB:IKE+1) &
+PDZX(IIE+1,:,IKB:IKE+1)+PDZX(IIE,:,IKB:IKE+1))/3.0)/8.0 * 0.5 )/12.0 &
-( (PRUCT(IIE-1,:,IKB:IKE+1)+PRUCT(IIE-1,:,IKB-1:IKE)) &
*PDZX(IIE-1,:,IKB:IKE+1) *0.5 &
+(TZHALO2_U%HALO2%EAST(:,IKB:IKE+1)+TZHALO2_U%HALO2%EAST(:,IKB-1:IKE)) &
*TZHALO2_DZX%HALO2%EAST(:,IKB:IKE+1) *0.5)/12.0
!
Z2(:,IJE,IKB:IKE+1)= &
7.0*( (PRVCT(:,IJE,IKB:IKE+1)+PRVCT(:,IJE,IKB-1:IKE)) &
*( 9.0*PDZY(:,IJE,IKB:IKE+1)-(PDZY(:,IJE+1,IKB:IKE+1) &
+PDZY(:,IJE,IKB:IKE+1)+PDZY(:,IJE-1,IKB:IKE+1))/3.0)/8.0 * 0.5 &
+(PRVCT(:,IJE+1,IKB:IKE+1)+PRVCT(:,IJE+1,IKB-1:IKE)) &
*( 9.0*PDZY(:,IJE+1,IKB:IKE+1)-(TZHALO2_DZY%HALO2%NORTH(:,IKB:IKE+1) &
+PDZY(:,IJE+1,IKB:IKE+1)+PDZY(:,IJE,IKB:IKE+1))/3.0)/8.0 * 0.5 )/12.0 &
-( (PRVCT(:,IJE-1,IKB:IKE+1)+PRVCT(:,IJE-1,IKB-1:IKE)) &
*PDZY(:,IJE-1,IKB:IKE+1) *0.5 &
+(TZHALO2_V%HALO2%NORTH(:,IKB:IKE+1)+TZHALO2_V%HALO2%NORTH(:,IKB-1:IKE)) &
*TZHALO2_DZY%HALO2%NORTH(:,IKB:IKE+1) *0.5)/12.0
!!$ END IF
!
!* 3.3 non-CYCLIC CASE IN THE X DIRECTION: 2nd order case
!
IF (HLBCX(1)/='CYCL' .AND. LWEST_ll()) THEN
!
Z1(IIB,:,IKB:IKE+1)= &
(PRUCT(IIB,:,IKB:IKE+1)+PRUCT(IIB,:,IKB-1:IKE) ) &
*PDZX(IIB,:,IKB:IKE+1) *0.25 &
+(PRUCT(IIB+1,:,IKB:IKE+1)+PRUCT(IIB+1,:,IKB-1:IKE) ) &
*PDZX(IIB+1,:,IKB:IKE+1) *0.25
END IF
!
IF (HLBCX(2)/='CYCL' .AND. LEAST_ll()) THEN
!
Z1(IIE,:,IKB:IKE+1)= &
(PRUCT(IIE,:,IKB:IKE+1)+PRUCT(IIE,:,IKB-1:IKE) ) &
*PDZX(IIE,:,IKB:IKE+1) *0.25 &
+(PRUCT(IIE+1,:,IKB:IKE+1)+PRUCT(IIE+1,:,IKB-1:IKE) ) &
*PDZX(IIE+1,:,IKB:IKE+1) *0.25
END IF
!
!* 3.4 non-CYCLIC CASE IN THE Y DIRECTION: 2nd order case
!
IF (HLBCY(1)/='CYCL' .AND. LSOUTH_ll()) THEN
!
Z2(:,IJB,IKB:IKE+1)= &
(PRVCT(:,IJB,IKB:IKE+1)+PRVCT(:,IJB,IKB-1:IKE) ) &
*PDZY(:,IJB,IKB:IKE+1) *0.25 &
+(PRVCT(:,IJB+1,IKB:IKE+1)+PRVCT(:,IJB+1,IKB-1:IKE) ) &
*PDZY(:,IJB+1,IKB:IKE+1) *0.25
!
END IF
!
IF (HLBCY(2)/='CYCL' .AND. LNORTH_ll()) THEN
!
Z2(:,IJE,IKB:IKE+1)= &
(PRVCT(:,IJE,IKB:IKE+1)+PRVCT(:,IJE,IKB-1:IKE) ) &
*PDZY(:,IJE,IKB:IKE+1) *0.25 &
+(PRVCT(:,IJE+1,IKB:IKE+1)+PRVCT(:,IJE+1,IKB-1:IKE) ) &
*PDZY(:,IJE+1,IKB:IKE+1) *0.25
!
END IF
!
!* 3.5 Vertical contyravariant wind
!
!
!!$ CALL GET_HALO(Z1)
!!$ CALL GET_HALO(Z2)
!!$
!!$ CALL MPPDB_CHECK3DM("contrav ::Z1/Z2/ PDZZ",PRECISION,Z1,Z2,PDZZ)
PRWCT=0.
PRWCT(IIB:IIE,IJB:IJE,IKB:IKE+1) = &
( PRWT(IIB:IIE,IJB:IJE,IKB:IKE+1) &
- Z1(IIB:IIE,IJB:IJE,IKB:IKE+1) &
- Z2(IIB:IIE,IJB:IJE,IKB:IKE+1) &
) / PDZZ(IIB:IIE,IJB:IJE,IKB:IKE+1)
!
END IF
!
PRWCT(:,:,1) = - PRWCT(:,:,3) ! Mirror hypothesis
!
IF (KADV_ORDER == 4 ) THEN
CALL CLEANLIST_ll(TZFIELD_U)
CALL CLEANLIST_ll(TZFIELD_V)
!!$ IF (NHALO==1) THEN
CALL CLEANLIST_ll(TZFIELD_DZX)
CALL CLEANLIST_ll(TZFIELD_DZY)
CALL DEL_HALO2_ll(TZHALO2_U)
CALL DEL_HALO2_ll(TZHALO2_V)
CALL DEL_HALO2_ll(TZHALO2_DZX)
CALL DEL_HALO2_ll(TZHALO2_DZY)
!!$ END IF
END IF
!-----------------------------------------------------------------------
IF (MPPDB_INITIALIZED) THEN
!Check all OUT arrays
CALL MPPDB_CHECK(PRUCT,"CONTRAV end:PRUCT")
CALL MPPDB_CHECK(PRVCT,"CONTRAV end:PRVCT")
CALL MPPDB_CHECK(PRWCT,"CONTRAV end:PRWCT")
END IF
!
END SUBROUTINE CONTRAV
!
#ifdef MNH_OPENACC
! ##############################################################
SUBROUTINE CONTRAV_DEVICE(HLBCX,HLBCY,PRUT,PRVT,PRWT,PDXX,PDYY,PDZZ,PDZX,PDZY, &
PRUCT,PRVCT,PRWCT,KADV_ORDER,Z1,Z2,ODATA_ON_DEVICE )
! ##############################################################
!
!!**** *CONTRAV * - computes the contravariant components from the
!! cartesian components
!!
!! PURPOSE
!! -------
! This routine computes the contravariant components of vector
! defined by its cartesian components (U,V,W) , using the following
! formulae:
! UC = U / DXX
! VC = V / DYY
! ( ----------x ----------y )
! ( ---z ---z )
! 1 ( U V )
! WC = --- ( W - DZX * --- - DZY * --- )
! DZZ ( DXX DYY )
!
!
! In the no-topography case, WC = W / DZZ
!
!
!!** METHOD
!! ------
!! We employ the Shuman operators to compute the averages. The metric
!! coefficients PDXX, PDYY, PDZX, PDZY, PDZZ are dummy arguments
!!
!!
!! EXTERNAL
!! --------
!! MXF, MYF, MZM : Shuman functions (mean operators)
!!
!! Module MODI_SHUMAN : Interface for Shuman functions
!!
!!
!! IMPLICIT ARGUMENTS
!! ------------------
!!
!! Module MODD_CONF : contains configuration variable
!! LFLAT : Logical for topography
!! = .TRUE. if Zs = 0 (Flat terrain)
!!
!! REFERENCE
!! ---------
!! Book2 of documentation (subroutine CONTRAV)
!!
!!
!! AUTHOR
!! ------
!! J.L. Redelsperger * CNRM *
!! J.-P. Pinty * Laboratoire d'Aerologie*
!!
!! MODIFICATIONS
!! -------------
!! Original 27/07/94
!! Corrections 3/08/94 (by J.P. Lafore)
!! Corrections 17/10/94 (by J.P. Lafore) WC modified for w-advection
!! Corrections 19/01/11 (by J.P. Pinty) WC 4th order
!! Corrections 28/03/11 (by V.Masson) // of WC 4th order
!! J.Escobar 21/03/2013: for HALOK comment all NHALO=1 test
! P. Wautelet 26/06/2019: optimisation for GPU + improve readability
!----------------------------------------------------------------------------
!
!* 0. DECLARATIONS
! ------------
USE MODD_ARGSLIST_ll, ONLY: HALO2LIST_ll
USE MODD_CONF
USE MODD_GRID_n, ONLY: XZZ
USE MODD_PARAMETERS
!
USE MODE_ll
USE MODE_MPPDB
#ifdef MNH_OPENACC
use mode_msg
#endif
!
USE MODI_GET_HALO
USE MODI_SHUMAN
!
IMPLICIT NONE
!
!* 0.1 declarations of arguments
!
CHARACTER (LEN=4), DIMENSION(2), INTENT(IN) :: HLBCX ! X direction LBC type
CHARACTER (LEN=4), DIMENSION(2), INTENT(IN) :: HLBCY ! Y direction LBC type
!
REAL, DIMENSION(:,:,:), INTENT(IN) :: PRUT ! Cartesian comp along x
REAL, DIMENSION(:,:,:), INTENT(IN) :: PRVT ! Cartesian comp along y
REAL, DIMENSION(:,:,:), INTENT(IN) :: PRWT ! Cartesian comp along z
!
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDXX ! Metric coefficients
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDYY ! Metric coefficients
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDZZ ! Metric coefficients
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDZX ! Metric coefficients
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDZY ! Metric coefficients
!
!
REAL, DIMENSION(:,:,:), INTENT(OUT) :: PRUCT ! Contrav comp along x-bar
REAL, DIMENSION(:,:,:), INTENT(OUT) :: PRVCT ! Contrav comp along y-bar
REAL, DIMENSION(:,:,:), INTENT(OUT) :: PRWCT ! Contrav comp along z-bar
INTEGER, INTENT(IN) :: KADV_ORDER ! Order of the advection scheme
REAL, DIMENSION(:,:,:), INTENT(OUT) :: Z1,Z2 ! Work arrays
LOGICAL, OPTIONAL, INTENT(IN) :: ODATA_ON_DEVICE ! Is some of the data on the accelerator device
!
!
!* 0.2 declarations of local variables
!
integer :: ji, jj, jk
INTEGER :: IIB, IIE, IJB, IJE, IKB, IKE
INTEGER :: IIU, IJU, IKU
INTEGER :: IW, IE, IS, IN ! Coordinate of fourth order diffusion area
INTEGER :: IINFO_ll
LOGICAL :: GDATA_ON_DEVICE
real :: ZTMP1, ZTMP2 ! Intermediate work variables
REAL, DIMENSION(:,:), POINTER , CONTIGUOUS :: ZU_EAST, ZV_NORTH, ZDZX_EAST, ZDZY_NORTH
TYPE(LIST_ll), POINTER :: TZFIELD_U, TZFIELD_V, TZFIELD_DZX, TZFIELD_DZY
TYPE(HALO2LIST_ll), POINTER :: TZHALO2_U, TZHALO2_V, TZHALO2_DZX, TZHALO2_DZY
!$acc data present( PRUT, PRVT, PRWT, PDXX, PDYY, PDZZ, PDZX, PDZY, PRUCT, PRVCT, PRWCT, Z1, Z2 )
IF ( PRESENT(ODATA_ON_DEVICE) ) THEN
GDATA_ON_DEVICE = ODATA_ON_DEVICE
ELSE
GDATA_ON_DEVICE = .FALSE.
END IF
!-----------------------------------------------------------------------
!
!* 1. Compute the horizontal contravariant components
! -----------------------------------------------
!
IF (MPPDB_INITIALIZED) THEN
!Check all IN arrays
CALL MPPDB_CHECK(PRUT,"CONTRAV beg:PRUT")
CALL MPPDB_CHECK(PRVT,"CONTRAV beg:PRVT")
CALL MPPDB_CHECK(PRWT,"CONTRAV beg:PRWT")
CALL MPPDB_CHECK(PDXX,"CONTRAV beg:PDXX")
CALL MPPDB_CHECK(PDYY,"CONTRAV beg:PDYY")
CALL MPPDB_CHECK(PDZZ,"CONTRAV beg:PDZZ")
CALL MPPDB_CHECK(PDZX,"CONTRAV beg:PDZX")
CALL MPPDB_CHECK(PDZY,"CONTRAV beg:PDZY")
END IF
!
IIU= SIZE(PDXX,1)
IJU= SIZE(PDXX,2)
IKU= SIZE(PDXX,3)
!
CALL GET_INDICE_ll( IIB,IJB,IIE,IJE)
!
IKB=1+JPVEXT
IKE=IKU - JPVEXT
!
IF (GDATA_ON_DEVICE) THEN
!PW TODO:remplacer (ailleurs aussi...) 1/PDXX... par PINV_PDXX (fait pour la turbulence...) cfr MNH/turb_hor_splt.f90
!$acc kernels
PRUCT(:,:,:) = PRUT(:,:,:) / PDXX(:,:,:)
PRVCT(:,:,:) = PRVT(:,:,:) / PDYY(:,:,:)
!$acc end kernels
!$acc update self(PRUCT,PRVCT)
ELSE
PRUCT(:,:,:) = PRUT(:,:,:) / PDXX(:,:,:)
PRVCT(:,:,:) = PRVT(:,:,:) / PDYY(:,:,:)
END IF
!
IF (KADV_ORDER == 4 ) THEN
IF( .NOT. LFLAT) THEN
!!$ NULLIFY(TZFIELD_U)
!!$ NULLIFY(TZFIELD_V)
!!$ CALL ADD3DFIELD_ll( TZFIELD_U, PRUCT, 'CONTRAV::PRUCT' )
!!$ CALL ADD3DFIELD_ll( TZFIELD_V, PRVCT, 'CONTRAV::PRVCT' )
!!$ CALL UPDATE_HALO_ll(TZFIELD_U,IINFO_ll)
!!$ CALL UPDATE_HALO_ll(TZFIELD_V,IINFO_ll)
!!$ !!$ IF( NHALO==1 ) THEN
!!$ NULLIFY(TZFIELD_DZX)
!!$ NULLIFY(TZFIELD_DZY)
!!$ CALL ADD3DFIELD_ll( TZFIELD_DZX, PDZX, 'CONTRAV::PDZX' )
!!$ CALL ADD3DFIELD_ll( TZFIELD_DZY, PDZY, 'CONTRAV::PDZY' )
!!$ NULLIFY(TZHALO2_U)
!!$ NULLIFY(TZHALO2_V)
!!$ NULLIFY(TZHALO2_DZX)
!!$ NULLIFY(TZHALO2_DZY)
!!$ CALL INIT_HALO2_ll(TZHALO2_U,1,IIU,IJU,IKU)
!!$ CALL INIT_HALO2_ll(TZHALO2_V,1,IIU,IJU,IKU)
!!$ CALL INIT_HALO2_ll(TZHALO2_DZX,1,IIU,IJU,IKU)
!!$ CALL INIT_HALO2_ll(TZHALO2_DZY,1,IIU,IJU,IKU)
!!$ CALL UPDATE_HALO2_ll(TZFIELD_U, TZHALO2_U, IINFO_ll)
!!$ CALL UPDATE_HALO2_ll(TZFIELD_V, TZHALO2_V, IINFO_ll)
!!$ CALL UPDATE_HALO2_ll(TZFIELD_DZX, TZHALO2_DZX, IINFO_ll)
!!$ CALL UPDATE_HALO2_ll(TZFIELD_DZY, TZHALO2_DZY, IINFO_ll)
!
CALL GET_HALO2_D(PRUCT,TZHALO2_U,'CONTRAV::PRUCT')
CALL GET_HALO2_D(PRVCT,TZHALO2_V,'CONTRAV::PRVCT')
CALL GET_HALO2_D(PDZX,TZHALO2_DZX,'CONTRAV::PDZX')
CALL GET_HALO2_D(PDZY,TZHALO2_DZY,'CONTRAV::PDZY')
!!$!$acc update device(PRUCT,PRVCT)
!!$ !!$ END IF
!
!PW: necessary because pointers does not work with OpenACC (PGI 16.1)
!!$ ALLOCATE(ZU_EAST(IJU,IKU),ZV_NORTH(IIU,IKU),ZDZX_EAST(IJU,IKU),ZDZY_NORTH(IIU,IKU))
!!$ !$acc enter data create( zu_east, zv_north, zdzx_east, zdzy_north )
!!$ !$acc kernels
ZU_EAST => TZHALO2_U%HALO2%EAST
ZDZX_EAST => TZHALO2_DZX%HALO2%EAST
ZV_NORTH => TZHALO2_V%HALO2%NORTH
ZDZY_NORTH => TZHALO2_DZY%HALO2%NORTH
!!$ !$acc end kernels
!!$!$acc update device(ZU_EAST,ZV_NORTH,ZDZX_EAST,ZDZY_NORTH)
END IF
END IF
!
!
!* 2. Compute the vertical contravariant components (flat case)
! ------------------------------------
!
FLAT: IF (LFLAT) THEN
IF (GDATA_ON_DEVICE) THEN
!$acc kernels
PRWCT(:,:,:) = PRWT(:,:,:) / PDZZ(:,:,:)
!$acc end kernels
!$acc update self(PRWCT)
ELSE
PRWCT(:,:,:) = PRWT(:,:,:) / PDZZ(:,:,:)
END IF
ELSE
!
!* 3. Compute the vertical contravariant components (general case)
! ------------------------------------
!
!$acc kernels
! Z1(:,:,:) = 0.
! Z2(:,:,:) = 0.
!
IF (KADV_ORDER == 2 ) THEN
#ifdef MNH_OPENACC
call Print_msg( NVERB_WARNING, 'GEN', 'CONTRAV', 'OpenACC: KADV_ORDER=2 and LFLAT=.TRUE. not yet tested' )
#endif
!
!$acc loop independent collapse(3)
do jk = ikb, ike + 1
do jj = 1, iju
do ji = iib, iie
Z1(ji, jj, jk ) = ( PRUCT(ji, jj, jk ) + PRUCT(ji, jj, jk - 1 ) ) * PDZX (ji, jj, jk ) * 0.25 &
+ ( PRUCT(ji + 1, jj, jk ) + PRUCT(ji + 1, jj, jk - 1 ) ) * PDZX (ji + 1, jj, jk ) * 0.25
end do
end do
end do
!$acc loop independent collapse(3)
do jk = ikb, ike + 1
do jj = ijb, ije
do ji = 1, iiu
Z2(:, jj, jk ) = ( PRVCT(:, jj, jk) + PRVCT( :, jj, jk - 1) ) * PDZY(:, jj, jk) * 0.25 &
+ ( PRVCT(:, jj + 1, jk) + PRVCT( :, jj + 1,jk - 1) ) * PDZY(:, jj + 1, jk) * 0.25
end do
end do
end do
PRWCT(:,:,:)=0.
!$acc loop independent collapse(3)
do jk = ikb, ike + 1
do jj = ijb, ije
do ji = iib, iie
PRWCT(ji ,jj, jk ) = ( PRWT(ji ,jj, jk ) - Z1(ji ,jj, jk ) - Z2(ji ,jj, jk ) ) / PDZZ(ji ,jj, jk )
end do
end do
end do
!
ELSE IF (KADV_ORDER == 4 ) THEN
!
!!$ IF (NHALO == 1) THEN
IF ( LWEST_ll() .AND. HLBCX(1)/='CYCL' ) THEN
IW=IIB+2 -1
ELSE
IW=IIB+1 -1
END IF
IE=IIE-1
!!$ ELSE
!!$ IF (LWEST_ll()) THEN
!!$ IW=IIB+1
!!$ ELSE
!!$ IW=IIB
!!$ END IF
!!$ IF (LEAST_ll() .AND. HLBCX(2)/='CYCL' ) THEN
!!$ IE=IIE-1
!!$ ELSE
!!$ IE=IIE
!!$ END IF
!!$ END IF
!
!!$ IF(NHALO == 1) THEN
IF ( LSOUTH_ll() .AND. HLBCY(1)/='CYCL' ) THEN
IS=IJB+2 -1
ELSE
IS=IJB+1 -1
END IF
IN=IJE-1
!!$ ELSE
!!$ IF (LSOUTH_ll()) THEN
!!$ IS=IJB+1
!!$ ELSE
!!$ IS=IJB
!!$ END IF
!!$ IF (LNORTH_ll() .AND. HLBCY(2)/='CYCL' ) THEN
!!$ IN=IJE-1
!!$ ELSE
!!$ IN=IJE
!!$ END IF
!!$ END IF
!
!
!* 3.1 interior of the process subdomain
!
!
!PW: OpenACC remarks: *computing only ztmp2 and reusing it at next iteration works
! but ji loop can not be collapsed -> 10x slower on GPU
! *ztmp1 and ztmp2 are not necessary but improve readability (no impact on performance)
!$acc loop independent collapse(3) private(ztmp1, ztmp2)
do jk = IKB, IKE + 1
do jj = 1, iju
do ji = IW, IE
ztmp1 = ( 9.0 * PDZX(ji, jj, jk ) - ( PDZX(ji+1, jj, jk ) + PDZX(ji, jj, jk ) + PDZX(ji-1, jj, jk ) ) / 3.0 ) / 16.0
ztmp2 = ( 9.0 * PDZX(ji+1, jj, jk ) - ( PDZX(ji+2, jj, jk ) + PDZX(ji+1, jj, jk ) + PDZX(ji, jj, jk ) ) / 3.0 ) / 16.0
Z1(ji, jj, jk ) = 7.0 * ( ( PRUCT(ji, jj, jk ) + PRUCT(ji, jj, jk-1 ) ) * ztmp1 &
+ ( PRUCT(ji+1, jj, jk ) + PRUCT(ji+1, jj, jk-1 ) ) * ztmp2 ) / 12.0 &
- 0.5 * ( ( PRUCT(ji-1, jj, jk ) + PRUCT(ji-1, jj, jk-1 ) ) * PDZX(ji-1, jj, jk) &
+ ( PRUCT(ji+2, jj, jk ) + PRUCT(ji+2, jj, jk-1 ) ) * PDZX(ji+2, jj, jk) ) / 12.0
end do
end do
end do
!
!$acc loop independent collapse(3)
do jk = IKB, IKE + 1
do jj = is, in
do ji = 1, iiu
ztmp1 = ( 9.0 * PDZY(ji, jj, jk ) - ( PDZY(ji, jj+1, jk ) + PDZY(ji, jj, jk ) + PDZY(ji, jj-1, jk ) ) / 3.0 ) / 16.0
ztmp2 = ( 9.0 * PDZY(ji, jj+1, jk ) - ( PDZY(ji, jj+2, jk ) + PDZY(ji, jj+1, jk ) + PDZY(ji, jj, jk ) ) / 3.0 ) / 16.0
Z2(ji, jj, jk ) = 7.0 * ( ( PRVCT(ji, jj, jk ) + PRVCT(ji, jj, jk-1 ) ) * ztmp1 &
+ ( PRVCT(ji, jj+1, jk ) + PRVCT(ji, jj+1, jk-1 ) ) * ztmp2 ) / 12.0 &
- 0.5 * ( ( PRVCT(ji, jj-1, jk ) + PRVCT(ji, jj-1, jk-1 ) ) * PDZY(ji, jj-1, jk ) &
+ ( PRVCT(ji, jj+2, jk ) + PRVCT(ji, jj+2, jk-1 ) ) * PDZY(ji, jj+2, jk ) ) / 12.0
end do
end do
end do
!
!* 3.2 limits of the process subdomain (inside the whole domain or in cyclic conditions)
!
!!$ IF (NHALO==1) THEN
!$acc loop independent collapse(2)
do jk = IKB, IKE + 1
do jj = 1, iju
ztmp1 = ( 9.0 * PDZX(IIE, jj, jk ) - ( PDZX(IIE+1, jj, jk ) + PDZX(IIE, jj, jk ) + PDZX(IIE-1, jj, jk ) ) / 3.0 ) / 16.0
ztmp2 = ( 9.0 * PDZX(IIE+1, jj, jk ) - ( ZDZX_EAST(jj, jk ) + PDZX(IIE+1, jj, jk ) + PDZX(IIE, jj, jk ) ) / 3.0 ) / 16.0
Z1(IIE, jj, jk ) = 7.0 * ( ( PRUCT(IIE, jj, jk ) + PRUCT(IIE, jj, jk-1 ) ) * ztmp1 &
+ ( PRUCT(IIE+1, jj, jk ) + PRUCT(IIE+1, jj, jk-1 ) ) * ztmp2 ) / 12.0 &
- 0.5 * ( ( PRUCT(IIE-1, jj, jk ) + PRUCT(IIE-1, jj, jk-1 ) ) * PDZX(IIE-1, jj, jk) &
+ ( ZU_EAST (jj, jk ) + ZU_EAST (jj, jk-1 ) ) * ZDZX_EAST (jj, jk) ) / 12.0
end do
end do
!
!$acc loop independent collapse(2)
do jk = IKB, IKE + 1
do ji = 1, iiu
ztmp1 = ( 9.0 * PDZY(ji, IJE, jk) - ( PDZY (ji, IJE+1, jk) + PDZY(ji, IJE, jk) + PDZY(ji, IJE-1, jk) ) / 3.0 ) / 16.0
ztmp2 = ( 9.0 * PDZY(ji, IJE+1, jk) - ( ZDZY_NORTH(ji, jk) + PDZY(ji, IJE+1, jk) + PDZY(ji, IJE, jk) ) / 3.0 ) / 16.0
Z2(ji, IJE, jk ) = 7.0 * ( ( PRVCT (ji, IJE, jk ) + PRVCT (ji, IJE, jk-1 ) ) * ztmp1 &
+ ( PRVCT (ji, IJE+1, jk ) + PRVCT (ji, IJE+1, jk-1 ) ) * ztmp2 ) / 12.0 &
- 0.5 * ( ( PRVCT (ji, IJE-1, jk ) + PRVCT (ji, IJE-1, jk-1 ) ) * PDZY (ji, IJE-1, jk ) &
+ ( ZV_NORTH(ji, jk ) + ZV_NORTH(ji, jk-1 ) ) * ZDZY_NORTH(ji, jk ) ) / 12.0
end do
end do
!!$ END IF
!
!* 3.3 non-CYCLIC CASE IN THE X DIRECTION: 2nd order case
!
IF (HLBCX(1)/='CYCL' .AND. LWEST_ll()) THEN
Z1(IIB, :, IKB:IKE+1 ) = ( PRUCT(IIB, :, IKB:IKE+1 ) + PRUCT(IIB, :, IKB-1:IKE ) ) * PDZX(IIB, :, IKB:IKE+1 ) * 0.25 &
+ ( PRUCT(IIB+1, :, IKB:IKE+1 ) + PRUCT(IIB+1, :, IKB-1:IKE ) ) * PDZX(IIB+1, :, IKB:IKE+1 ) * 0.25
END IF
!
IF (HLBCX(2)/='CYCL' .AND. LEAST_ll()) THEN
Z1(IIE, :, IKB:IKE+1 ) = ( PRUCT(IIE, :, IKB:IKE+1 ) + PRUCT(IIE, :, IKB-1:IKE ) ) * PDZX(IIE, :, IKB:IKE+1 ) * 0.25 &
+ ( PRUCT(IIE+1, :, IKB:IKE+1 ) + PRUCT(IIE+1, :, IKB-1:IKE ) ) * PDZX(IIE+1, :, IKB:IKE+1 ) * 0.25
END IF
!
!* 3.4 non-CYCLIC CASE IN THE Y DIRECTION: 2nd order case
!
IF (HLBCY(1)/='CYCL' .AND. LSOUTH_ll()) THEN
Z2(:, IJB, IKB:IKE+1 ) = ( PRVCT(:, IJB, IKB:IKE+1 ) + PRVCT(:, IJB, IKB-1:IKE ) ) * PDZY(:, IJB, IKB:IKE+1 ) * 0.25 &
+ ( PRVCT(:, IJB+1, IKB:IKE+1 ) + PRVCT(:, IJB+1, IKB-1:IKE ) ) * PDZY(:, IJB+1, IKB:IKE+1 ) * 0.25
END IF
!
IF (HLBCY(2)/='CYCL' .AND. LNORTH_ll()) THEN
Z2(:, IJE, IKB:IKE+1 ) = ( PRVCT(:, IJE, IKB:IKE+1 ) + PRVCT(:, IJE, IKB-1:IKE ) ) * PDZY(:, IJE, IKB:IKE+1 ) * 0.25 &
+ ( PRVCT(:, IJE+1, IKB:IKE+1 ) + PRVCT(:, IJE+1, IKB-1:IKE ) ) * PDZY(:, IJE+1, IKB:IKE+1 ) * 0.25
END IF
!
!* 3.5 Vertical contyravariant wind
!
!
!!$ CALL GET_HALO(Z1)
!!$ CALL GET_HALO(Z2)
!!$
!!$ CALL MPPDB_CHECK3DM("contrav_device ::Z1/Z2/ PDZZ",PRECISION,Z1,Z2,PDZZ)
PRWCT(:,:,:)=0.
!$acc loop independent collapse(3)
do jk = ikb, ike + 1
do jj = ijb, ije
do ji = iib, iie
PRWCT(ji ,jj, jk ) = ( PRWT(ji ,jj, jk ) - Z1(ji ,jj, jk ) - Z2(ji ,jj, jk ) ) / PDZZ(ji ,jj, jk )
end do
end do
end do
!
!
END IF
!
PRWCT(:,:,1) = - PRWCT(:,:,3) ! Mirror hypothesis
!$acc end kernels
!$acc update self(PRWCT)
!
IF (KADV_ORDER == 4 ) THEN
!!$!$acc exit data delete( zu_east, zv_north, zdzx_east, zdzy_north )
!!$ DEALLOCATE(ZU_EAST,ZV_NORTH,ZDZX_EAST,ZDZY_NORTH)
!!$ CALL CLEANLIST_ll(TZFIELD_U)
!!$ CALL CLEANLIST_ll(TZFIELD_V)
!!$ !!$ IF (NHALO==1) THEN
!!$ CALL CLEANLIST_ll(TZFIELD_DZX)
!!$ CALL CLEANLIST_ll(TZFIELD_DZY)
CALL DEL_HALO2_ll(TZHALO2_U)
CALL DEL_HALO2_ll(TZHALO2_V)
CALL DEL_HALO2_ll(TZHALO2_DZX)
CALL DEL_HALO2_ll(TZHALO2_DZY)
!!$ !!$ END IF
END IF
END IF FLAT
!-----------------------------------------------------------------------
IF (MPPDB_INITIALIZED) THEN
!Check all OUT arrays
CALL MPPDB_CHECK(PRUCT,"CONTRAV end:PRUCT")
CALL MPPDB_CHECK(PRVCT,"CONTRAV end:PRVCT")
CALL MPPDB_CHECK(PRWCT,"CONTRAV end:PRWCT")
END IF
!$acc end data
END SUBROUTINE CONTRAV_DEVICE
#endif