Newer
Older
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
! ######spl
FUNCTION GX_V_UV(PA,PDXX,PDZZ,PDZX, KKA, KKU, KL) RESULT(PGX_V_UV)
USE PARKIND1, ONLY : JPRB
USE YOMHOOK , ONLY : LHOOK, DR_HOOK
! #########################################################
!
!!**** *GX_V_UV* - Cartesian Gradient operator:
!! computes the gradient in the cartesian X
!! direction for a variable placed at the
!! V point and the result is placed at
!! the UV vorticity point.
!! PURPOSE
!! -------
! The purpose of this function is to compute the discrete gradient
! along the X cartesian direction for a field PA placed at the
! V point. The result is placed at the UV vorticity point.
!
!
! ( _________________z )
! ( (___y _________x ) )
! 1 ( (d*zx (dzm(PA))) ) )
! PGX_V_UV= ---- (dxm(PA) - ( (------ ) ) )
! ___y ( ( ( ___y ) ) )
! d*xx ( ( ( d*zz ) ) )
!
!
!
!!** METHOD
!! ------
!! The Chain rule of differencing is applied to variables expressed
!! in the Gal-Chen & Somerville coordinates to obtain the gradient in
!! the cartesian system
!!
!! EXTERNAL
!! --------
!! MXM,MZF,MYM : Shuman functions (mean operators)
!! DXM,DZM : Shuman functions (finite difference operators)
!!
!! IMPLICIT ARGUMENTS
!! ------------------
!! NONE
!!
!! REFERENCE
!! ---------
!! Book2 of documentation of Meso-NH (GRAD_CAR operators)
!! A Turbulence scheme for the Meso-NH model (Chapter 6)
!!
!! AUTHOR
!! ------
!! Joan Cuxart *INM and Meteo-France*
!!
!! MODIFICATIONS
!! -------------
!! Original 20/07/94
!! 18/10/00 (V.Masson) add LFLAT switch
!-------------------------------------------------------------------------
!
!* 0. DECLARATIONS
!
!
USE MODI_SHUMAN, ONLY: DXM, MZF, DZM, MYM, MXM
USE MODD_CONF
!
IMPLICIT NONE
!
!
!* 0.1 declarations of arguments and result
!
INTEGER, INTENT(IN) :: KKA, KKU ! near ground and uppest atmosphere array indexes
INTEGER, INTENT(IN) :: KL ! +1 if grid goes from ground to atmosphere top, -1 otherwise
REAL, DIMENSION(:,:,:), INTENT(IN) :: PA ! variable at the V point
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDXX ! metric coefficient dxx
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDZZ ! metric coefficient dzz
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDZX ! metric coefficient dzx
!
REAL, DIMENSION(SIZE(PA,1),SIZE(PA,2),SIZE(PA,3)) :: PGX_V_UV ! result UV point
!
!
!* 0.2 declaration of local variables
!
! NONE
!
!----------------------------------------------------------------------------
!
!* 1. DEFINITION of GX_V_UV
! ---------------------
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (LHOOK) CALL DR_HOOK('GX_V_UV',0,ZHOOK_HANDLE)
IF (.NOT. LFLAT) THEN
PGX_V_UV(:,:,:)= ( DXM(PA)- MZF(MXM(DZM(PA, KKA, KKU, KL)/&
MYM(PDZZ) ) *MYM(PDZX), KKA, KKU, KL)) / MYM(PDXX)
ELSE
PGX_V_UV(:,:,:)= DXM(PA) / MYM(PDXX)
END IF
!
!----------------------------------------------------------------------------
!
IF (LHOOK) CALL DR_HOOK('GX_V_UV',1,ZHOOK_HANDLE)
END FUNCTION GX_V_UV
! ######spl
FUNCTION GY_V_M(PA,PDYY,PDZZ,PDZY, KKA, KKU, KL) RESULT(PGY_V_M)
USE PARKIND1, ONLY : JPRB
USE YOMHOOK , ONLY : LHOOK, DR_HOOK
! #######################################################
!
!!**** *GY_V_M* - Cartesian Gradient operator:
!! computes the gradient in the cartesian Y
!! direction for a variable placed at the
!! V point and the result is placed at
!! the mass point.
!! PURPOSE
!! -------
! The purpose of this function is to compute the discrete gradient
! along the Y cartesian direction for a field PA placed at the
! V point. The result is placed at the mass point.
!
!
! ( ______________z )
! ( (___________y ) )
! 1 ( (d*zy dzm(PA) ) )
! PGY_V_M = ---- (dyf(PA) - (------------)) )
! ___y ( ( ) )
! d*yy ( ( d*zz ) )
!
!
!!** METHOD
!! ------
!! The Chain rule of differencing is applied to variables expressed
!! in the Gal-Chen & Somerville coordinates to obtain the gradient in
!! the cartesian system
!!
!! EXTERNAL
!! --------
!! MYF,MZF : Shuman functions (mean operators)
!! DYF,DZF : Shuman functions (finite difference operators)
!!
!! IMPLICIT ARGUMENTS
!! ------------------
!! NONE
!!
!! REFERENCE
!! ---------
!! Book2 of documentation of Meso-NH (GRAD_CAR operators)
!! A Turbulence scheme for the Meso-NH model (Chapter 6)
!!
!! AUTHOR
!! ------
!! Joan Cuxart *INM and Meteo-France*
!!
!! MODIFICATIONS
!! -------------
!! Original 19/07/94
!! 18/10/00 (V.Masson) add LFLAT switch
!-------------------------------------------------------------------------
!
!* 0. DECLARATIONS
!
!
USE MODI_SHUMAN, ONLY: DYF, MZF, MYF, DZM
USE MODD_CONF
!
IMPLICIT NONE
!
!
!* 0.1 declarations of arguments and result
!
INTEGER, INTENT(IN) :: KKA, KKU ! near ground and uppest atmosphere array indexes
INTEGER, INTENT(IN) :: KL ! +1 if grid goes from ground to atmosphere top, -1 otherwise
REAL, DIMENSION(:,:,:), INTENT(IN) :: PA ! variable at the V point
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDYY ! metric coefficient dyy
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDZZ ! metric coefficient dzz
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDZY ! metric coefficient dzy
!
REAL, DIMENSION(SIZE(PA,1),SIZE(PA,2),SIZE(PA,3)) :: PGY_V_M ! result mass point
!
!
!* 0.2 declaration of local variables
!
! NONE
!
!----------------------------------------------------------------------------
!
!* 1. DEFINITION of GY_V_M
! --------------------
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (LHOOK) CALL DR_HOOK('GY_V_M',0,ZHOOK_HANDLE)
IF (.NOT. LFLAT) THEN
PGY_V_M(:,:,:)= (DYF(PA) - &
MZF(MYF(PDZY*DZM(PA, KKA, KKU, KL))/PDZZ, KKA, KKU, KL) &
) / MYF(PDYY)
ELSE
PGY_V_M(:,:,:)= DYF(PA) / MYF(PDYY)
END IF
!
!----------------------------------------------------------------------------
!
IF (LHOOK) CALL DR_HOOK('GY_V_M',1,ZHOOK_HANDLE)
END FUNCTION GY_V_M
! ######spl
FUNCTION GZ_V_VW(PA,PDZZ, KKA, KKU, KL) RESULT(PGZ_V_VW)
USE PARKIND1, ONLY : JPRB
USE YOMHOOK , ONLY : LHOOK, DR_HOOK
! #######################################################
!
!!**** *GZ_V_VW - Cartesian Gradient operator:
!! computes the gradient in the cartesian Z
!! direction for a variable placed at the
!! V point and the result is placed at
!! the VW vorticity point.
!! PURPOSE
!! -------
! The purpose of this function is to compute the discrete gradient
! along the Z cartesian direction for a field PA placed at the
! V point. The result is placed at the VW vorticity point.
!
!
! dzm(PA)
! PGZ_V_VW = ------
! ____y
! d*zz
!
!!** METHOD
!! ------
!! The Chain rule of differencing is applied to variables expressed
!! in the Gal-Chen & Somerville coordinates to obtain the gradient in
!! the cartesian system
!!
!! EXTERNAL
!! --------
!! MYM : Shuman functions (mean operators)
!! DZM : Shuman functions (finite difference operators)
!!
!! IMPLICIT ARGUMENTS
!! ------------------
!! NONE
!!
!! REFERENCE
!! ---------
!! Book2 of documentation of Meso-NH (GRAD_CAR operators)
!! A Turbulence scheme for the Meso-NH model (Chapter 6)
!!
!! AUTHOR
!! ------
!! Joan Cuxart *INM and Meteo-France*
!!
!! MODIFICATIONS
!! -------------
!! Original 20/07/94
!-------------------------------------------------------------------------
!
!* 0. DECLARATIONS
!
!
USE MODI_SHUMAN, ONLY: DZM, MYM
!
IMPLICIT NONE
!
!
!* 0.1 declarations of arguments and result
!
INTEGER, INTENT(IN) :: KKA, KKU ! near ground and uppest atmosphere array indexes
INTEGER, INTENT(IN) :: KL ! +1 if grid goes from ground to atmosphere top, -1 otherwise
REAL, DIMENSION(:,:,:), INTENT(IN) :: PA ! variable at the V point
REAL, DIMENSION(:,:,:), INTENT(IN) :: PDZZ ! metric coefficient dzz
!
REAL, DIMENSION(SIZE(PA,1),SIZE(PA,2),SIZE(PA,3)) :: PGZ_V_VW ! result VW point
!
!
!* 0.2 declaration of local variables
!
! NONE
!
!----------------------------------------------------------------------------
!
!* 1. DEFINITION of GZ_V_VW
! ---------------------
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
IF (LHOOK) CALL DR_HOOK('GZ_V_VW',0,ZHOOK_HANDLE)
PGZ_V_VW(:,:,:)= DZM(PA, KKA, KKU, KL) / MYM(PDZZ)
!
!----------------------------------------------------------------------------
!
IF (LHOOK) CALL DR_HOOK('GZ_V_VW',1,ZHOOK_HANDLE)
END FUNCTION GZ_V_VW